FLASH中的trace只能在FLASH　IDE中跟蹤看到，如果你將SWF發(fā)布到網(wǎng)上，是看不到trace的調(diào)試信息，這給開(kāi)發(fā)網(wǎng)絡(luò)FLASH帶來(lái)的調(diào)試上的困難，那有沒(méi)有好的辦法來(lái)解決這個(gè)問(wèn)題呢，不管SWF發(fā)布到什么地方，打開(kāi)一個(gè)本地SWF跟蹤器來(lái)接收調(diào)試消息那豈不是很好，因?yàn)槲覈L試了各種方法，從SharedObject的本地對(duì)象到遠(yuǎn)程對(duì)象到LocalConnection的方法都嘗試一遍（使用LocalConnection是從Breeze AddIn中發(fā)現(xiàn)的一個(gè)“秘密”，感覺(jué)SNOW給我了一個(gè)提示，發(fā)現(xiàn)了其中的“奧秘”），在需要調(diào)試的SWF中使用下面的類(lèi)：
class fj.util.JTracer {
    public static var debug:Boolean=true;
    private static var _instance:JTracer;
    private var _lc:LocalConnection;
    private function JTracer(){
        this._lc=new LocalConnection();
        this._lc.allowDomain=function(domain:String):Boolean{
            return true;
        }
    }
    public static function trace(msg:Object):Void{
        if(!JTracer.debug){
            return;
        }
        if(JTracer._instance==undefined){
            JTracer._instance=new JTracer();
        }
        JTracer._instance.traceMsg(msg);
    }
    private function traceMsg(msg:Object):Void{
        trace(msg);
        this._lc.send("localhost:trace","trace",this._lc.domain(),msg);
    }
}
使用方法很簡(jiǎn)單，就是JTracer.trace("我來(lái)試試!");
SWF跟蹤器中的代碼如下：
import fj.util.JDelegate;
class view.JDebug {
    private var _ui:MovieClip;
    private var _lc:LocalConnection;
    function JDebug(ui){
        this._ui=ui;
        this.init();
    }
    private function init(){
        this._lc=new LocalConnection();
        this._lc.allowDomain=function(domain):Boolean{
            return true;
        }
        this._lc.connect("trace");
        this._lc.trace=JDelegate.create(this,onTrace);
    }
    private function onTrace(domain:String,msg:Object){
        this._ui.msg_ta.text+=domain+":"+msg+"\n";
    }
}
這個(gè)需要放一個(gè)組件TextArea名字叫msg_ta,用來(lái)顯示跟蹤的消息！

最新評(píng)論