快捷導(dǎo)航

SQLServer 2008中SQL增強(qiáng)之三 Merge(在一條語(yǔ)句中使用Insert,Update,Delete)

更新時(shí)間：2011年05月08日 23:35:05 作者：

SQL　Server 2008提供了一個(gè)增強(qiáng)的SQL命令Merge，用法參看MSDN:http://msdn.microsoft.com/zh-cn/library/bb510625.aspx

功能：根據(jù)與源表聯(lián)接的結(jié)果，對(duì)目標(biāo)表執(zhí)行插入、更新或刪除操作。例如，根據(jù)在另一個(gè)表中找到的差異在一個(gè)表中插入、更新或刪除行，可以對(duì)兩個(gè)表進(jìn)行同步。

我們看一個(gè)例子，假如，有一總產(chǎn)品列表，一個(gè)分店產(chǎn)品列表，需要從分店添加產(chǎn)品時(shí)更新總產(chǎn)品列表。

總產(chǎn)品表，分店產(chǎn)品表結(jié)構(gòu)完全一致：

復(fù)制代碼代碼如下:

 
if OBJECT_ID('Demo_AllProducts') is not null 
drop table Demo_AllProducts 
go 
Create table Demo_AllProducts 
(PKID int not null identity(1,1) primary key 
,DName Nvarchar(20) null 
,DCode NVarchar(30) null 
,DDate datetime null 
) 
go 

--this SQL is only for SQL Server 2008 
Insert into Demo_AllProducts 
(DName,DCode,DDate) 
values 
('DemoA','AAA',GETDATE()), 
('DemoB','BBB',GETDATE()), 
('DemoC','CCC',GETDATE()), 
('DemoD','DDD',GETDATE()), 
('DemoE','EEE',GETDATE()) 

select * from Demo_AllProducts 

--PKID DName DCode DDate 
--1 DemoA AAA 2010-10-12 20:33:54.417 
--2 DemoB BBB 2010-10-12 20:33:54.417 
--3 DemoC CCC 2010-10-12 20:33:54.417 
--4 DemoD DDD 2010-10-12 20:33:54.417 
--5 DemoE EEE 2010-10-12 20:33:54.417 

if OBJECT_ID('Demo_Shop1_Product') is not null 
drop table Demo_Shop1_Product 
go 

Create table Demo_Shop1_Product 
(PKID int not null identity(1,1) primary key 
,DName Nvarchar(20) null 
,DCode NVarchar(30) null 
,DDate datetime null 
) 
go 

--this SQL is only for SQL Server 2008 
Insert into Demo_Shop1_Product 
(DName,DCode,DDate) 
values 
('DemoA','AAA',GETDATE()), 
('DemoB','CCC',GETDATE()), 
('DemoF','FFF',GETDATE()) 

select * from Demo_Shop1_Product 

--PKID DName DCode DDate 
--1 DemoA AAA 2010-10-17 20:19:32.767 
--2 DemoB CCC 2010-10-17 20:19:32.767 
--3 DemoF FFF 2010-10-17 20:19:32.767 

假定現(xiàn)在需要將分店數(shù)據(jù)完全合并到總產(chǎn)品表中，以編碼字段為依據(jù)，如果產(chǎn)品名稱不致，則用分店的產(chǎn)品名稱替換總產(chǎn)品名稱。

如果總產(chǎn)品表中不存在，則添加。

可選項(xiàng)：如果分店表中不存在，則從總產(chǎn)品表中刪除分店中沒(méi)有的行。如果這樣，總產(chǎn)品表和分店表就完全同步了。實(shí)際操作中可能不需要?jiǎng)h除目標(biāo)表的行。

語(yǔ)句如下：

復(fù)制代碼代碼如下:

 
--確定目標(biāo)表 
Merge Into Demo_AllProducts p 
--從數(shù)據(jù)源查找編碼相同的產(chǎn)品 
using Demo_Shop1_Product s on p.DCode=s.DCode 
--如果編碼相同，則更新目標(biāo)表的名稱 
When Matched and P.DName<>s.DName Then Update set P.DName=s.DName 
--如果目標(biāo)表中不存在，則從數(shù)據(jù)源插入目標(biāo)表 
When Not Matched By Target Then Insert (DName,DCode,DDate) values (s.DName,s.DCode,s.DDate) 
--如果數(shù)據(jù)源的行在源表中不存在，則刪除源表行 
When Not Matched By Source Then Delete; 

此時(shí)，執(zhí)行完成后，兩個(gè)表的行均如下：

復(fù)制代碼代碼如下:

 
--PKID DName DCode DDate 
--1 DemoA AAA 2010-10-17 20:31:00.827 
--2 DemoB CCC 2010-10-17 20:31:00.827 
--3 DemoF FFF 2010-10-17 20:31:00.827 

如果不刪除，語(yǔ)句如下：

復(fù)制代碼代碼如下:

 
--確定目標(biāo)表 
Merge Into Demo_AllProducts p 
--從數(shù)據(jù)源查找編碼相同的產(chǎn)品 
using Demo_Shop1_Product s on p.DCode=s.DCode 
--如果編碼相同，則更新目標(biāo)表的名稱 
When Matched and P.DName<>s.DName Then Update set P.DName=s.DName 
--如果目標(biāo)表中不存在，則從數(shù)據(jù)源插入目標(biāo)表 
When Not Matched By Target Then Insert (DName,DCode,DDate) values (s.DName,s.DCode,s.DDate); 

執(zhí)行后結(jié)果：

復(fù)制代碼代碼如下:

 
--PKID DName DCode DDate 
--1 DemoA AAA 2010-10-17 20:30:28.350 
--2 DemoB BBB 2010-10-17 20:30:28.350 
--3 DemoB CCC 2010-10-17 20:30:28.350 
--4 DemoD DDD 2010-10-17 20:30:28.350 
--5 DemoE EEE 2010-10-17 20:30:28.350 
--6 DemoF FFF 2010-10-17 20:31:00.827 

--PKID DName DCode DDate 
--1 DemoA AAA 2010-10-17 20:31:00.827 
--2 DemoB CCC 2010-10-17 20:31:00.827 
--3 DemoF FFF 2010-10-17 20:31:00.827 

如果需要記錄Merge語(yǔ)句影響的行，可以用Output子句，如果僅僅需要知道影響的行數(shù)，可以使用@@ROWCOUNT或ROWCOUNT_BIG()，修改后的示例如下：

復(fù)制代碼代碼如下:

 
--定義表變量以存儲(chǔ)輸出 
Declare @tableVarRecord Table 
(MPKID int not null identity(1,1) primary key 
,PKID int null 
,DName Nvarchar(20) null 
,DCode NVarchar(30) null 
,DDate datetime null 
) 

--確定目標(biāo)表 
Merge Into Demo_AllProducts p 
--從數(shù)據(jù)源查找編碼相同的產(chǎn)品 
using Demo_Shop1_Product s on p.DCode=s.DCode 
--如果編碼相同，則更新目標(biāo)表的名稱 
When Matched and P.DName<>s.DName Then 
Update set P.DName=s.DName 

--如果目標(biāo)表中不存在，則從數(shù)據(jù)源插入目標(biāo)表 
When Not Matched By Target Then 
Insert (DName,DCode,DDate) values (s.DName,s.DCode,s.DDate) 

--如果數(shù)據(jù)源的行在源表中不存在，則刪除源表行 
When Not Matched By Source Then 
Delete OUTPUT deleted.* INTO @tableVarRecord; 
----Delete OUTPUT Inserted.* INTO @tableVarRecord; 

--返回上個(gè)Merge語(yǔ)句影響的行數(shù) 
select @@ROWCOUNT as Count1,ROWCOUNT_BIG() as Count2 

select * from @tableVarRecord; 

結(jié)果：

復(fù)制代碼代碼如下:

 
--影響的行數(shù) 
--Count1 Count2 
--5 5 

--Deleted表的行 
--MPKID PKID DName DCode DDate 
--1 NULL NULL NULL NULL 
--2 2 DemoB BBB 2010-10-17 21:42:30.700 
--3 3 DemoC CCC 2010-10-17 21:42:30.700 
--4 4 DemoD DDD 2010-10-17 21:42:30.700 
--5 5 DemoE EEE 2010-10-17 21:42:30.700 

關(guān)于@@ROWCOUNT和ROWCOUNT_BIG()的更多說(shuō)明，請(qǐng)查閱MSDN:

http://technet.microsoft.com/zh-tw/library/ms187316.aspx

http://msdn.microsoft.com/en-us/library/ms181406.aspx

如果影響的結(jié)果超過(guò)20億，即整型的最大范圍，請(qǐng)使用后者。

邀月注：本文版權(quán)由邀月和博客園共同所有，轉(zhuǎn)載請(qǐng)注明出處。

您可能感興趣的文章: