自包含批處理

sp_executesql 或 EXECUTE 語句執(zhí)行字符串時，字符串被作為其自包含批處理執(zhí)行。SQL Server 將Transact-SQL 語句或字符串中的語句編譯進一個執(zhí)行計劃，該執(zhí)行計劃獨立于包含 sp_executesql 或 EXECUTE 語句的批處理的執(zhí)行計劃。下列規(guī)則適用于自含的批處理：

• 直到執(zhí)行 sp_executesql 或EXECUTE 語句時才將sp_executesql 或 EXECUTE 字符串中的 Transact-SQL 語句編譯進執(zhí)行計劃。執(zhí)行字符串時才開始分析或檢查其錯誤。執(zhí)行時才對字符串中引用的名稱進行解析。
• 執(zhí)行的字符串中的 Transact-SQL 語句，不能訪問 sp_executesql 或 EXECUTE 語句所在批處理中聲明的任何變量。包含 sp_executesql 或 EXECUTE 語句的批處理不能訪問執(zhí)行的字符串中定義的變量或局部游標。
• 如果執(zhí)行字符串有更改數據庫上下文的 USE 語句，則對數據庫上下文的更改僅持續(xù)到 sp_executesql 或 EXECUTE 語句完成。

通過執(zhí)行下列兩個批處理來舉例說明：

/* Show not having access to variables from the calling batch. */
DECLARE @CharVariable CHAR(3)
SET @CharVariable = 'abc'
/* sp_executesql fails because @CharVariable has gone out of scope. */
sp_executesql N'PRINT @CharVariable'
GO

/* Show database context resetting after sp_executesql completes. */
USE pubs
GO
sp_executesql N'USE Northwind'
GO
/* This statement fails because the database context
  has now returned to pubs. */
SELECT * FROM Shippers
GO

替換參數值

sp_executesql 支持對 Transact-SQL 字符串中指定的任何參數的參數值進行替換，但是 EXECUTE 語句不支持。因此，由 sp_executesql 生成的 Transact-SQL 字符串比由 EXECUTE 語句所生成的更相似。SQL Server 查詢優(yōu)化器可能將來自 sp_executesql 的 Transact-SQL 語句與以前所執(zhí)行的語句的執(zhí)行計劃相匹配，以節(jié)約編譯新的執(zhí)行計劃的開銷。

使用 EXECUTE 語句時，必須將所有參數值轉換為字符或 Unicode 并使其成為 Transact-SQL 字符串的一部分：

DECLARE @IntVariable INT
DECLARE @SQLString NVARCHAR(500)
/* Build and execute a string with one parameter value. */
SET @IntVariable = 35
SET @SQLString = N'SELECT * FROM pubs.dbo.employee WHERE job_lvl = ' +
         CAST(@IntVariable AS NVARCHAR(10))
EXEC(@SQLString)
/* Build and execute a string with a second parameter value. */
SET @IntVariable = 201
SET @SQLString = N'SELECT * FROM pubs.dbo.employee WHERE job_lvl = ' +
         CAST(@IntVariable AS NVARCHAR(10))
EXEC(@SQLString)

如果語句重復執(zhí)行，則即使僅有的區(qū)別是為參數所提供的值不同，每次執(zhí)行時也必須生成全新的 Transact-SQL 字符串。從而在下面幾個方面產生額外的開銷：

• SQL Server 查詢優(yōu)化器具有將新的 Transact-SQL 字符串與現有的執(zhí)行計劃匹配的能力，此能力被字符串文本中不斷更改的參數值妨礙，特別是在復雜的 Transact-SQL 語句中。
• 每次執(zhí)行時均必須重新生成整個字符串。
• 每次執(zhí)行時必須將參數值（不是字符或 Unicode 值）投影到字符或 Unicode 格式。

sp_executesql 支持與 Transact-SQL 字符串相獨立的參數值的設置：

DECLARE @IntVariable INT
DECLARE @SQLString NVARCHAR(500)
DECLARE @ParmDefinition NVARCHAR(500)

/* Build the SQL string once. */
SET @SQLString =
   N'SELECT * FROM pubs.dbo.employee WHERE job_lvl = @level'
/* Specify the parameter format once. */
SET @ParmDefinition = N'@level tinyint'

/* Execute the string with the first parameter value. */
SET @IntVariable = 35
EXECUTE sp_executesql @SQLString, @ParmDefinition,
           @level = @IntVariable
/* Execute the same string with the second parameter value. */
SET @IntVariable = 32
EXECUTE sp_executesql @SQLString, @ParmDefinition,
           @level = @IntVariable

此 sp_executesql 示例完成的任務與前面的 EXECUTE 示例所完成的相同，但有下列額外優(yōu)點：

• 因為 Transact-SQL 語句的實際文本在兩次執(zhí)行之間未改變，所以查詢優(yōu)化器應該能將第二次執(zhí)行中的 Transact-SQL 語句與第一次執(zhí)行時生成的執(zhí)行計劃匹配。這樣，SQL Server 不必編譯第二條語句。
• Transact-SQL 字符串只生成一次。
• 整型參數按其本身格式指定。不需要轉換為 Unicode。

說明  為了使 SQL Server 重新使用執(zhí)行計劃，語句字符串中的對象名稱必須完全符合要求。

重新使用執(zhí)行計劃

在 SQL Server 早期的版本中要重新使用執(zhí)行計劃的唯一方式是，將 Transact-SQL 語句定義為存儲過程然后使應用程序執(zhí)行此存儲過程。這就產生了管理應用程序的額外開銷。使用 sp_executesql 有助于減少此開銷，并使 SQL Server 得以重新使用執(zhí)行計劃。當要多次執(zhí)行某個 Transact-SQL 語句，且唯一的變化是提供給該 Transact-SQL 語句的參數值時，可以使用 sp_executesql 來代替存儲過程。因為 Transact-SQL 語句本身保持不變僅參數值變化，所以 SQL Server 查詢優(yōu)化器可能重復使用首次執(zhí)行時所生成的執(zhí)行計劃。

下例為服務器上除四個系統(tǒng)數據庫之外的每個數據庫生成并執(zhí)行 DBCC CHECKDB 語句：

USE master
GO
SET NOCOUNT ON
GO
DECLARE AllDatabases CURSOR FOR
SELECT name FROM sysdatabases WHERE dbid > 4

OPEN AllDatabases

DECLARE @DBNameVar NVARCHAR(128)
DECLARE @Statement NVARCHAR(300)

FETCH NEXT FROM AllDatabases INTO @DBNameVar
WHILE (@@FETCH_STATUS = 0)
BEGIN
  PRINT N'CHECKING DATABASE ' + @DBNameVar
  SET @Statement = N'USE ' + @DBNameVar + CHAR(13)
   + N'DBCC CHECKDB (' + @DBNameVar + N')'
  EXEC sp_executesql @Statement
  PRINT CHAR(13) + CHAR(13)
  FETCH NEXT FROM AllDatabases INTO @DBNameVar
END

CLOSE AllDatabases
DEALLOCATE AllDatabases
GO
SET NOCOUNT OFF
GO

當目前所執(zhí)行的 Transact-SQL 語句包含綁定參數標記時，SQL Server ODBC 驅動程序使用 sp_executesql 完成 SQLExecDirect。但例外情況是 sp_executesql 不用于執(zhí)行中的數據參數。這使得使用標準 ODBC 函數或使用在 ODBC 上定義的 API（如 RDO）的應用程序得以利用 sp_executesql 所提供的優(yōu)勢。定位于 SQL Server 2000 的現有的 ODBC 應用程序不需要重寫就可以自動獲得性能增益。有關更多信息，請參見使用語句參數。

用于 SQL Server 的 Microsoft OLE DB 提供程序也使用 sp_executesql 直接執(zhí)行帶有綁定參數的語句。使用 OLE DB 或 ADO 的應用程序不必重寫就可以獲得 sp_executesql 所提供的優(yōu)勢。

1、執(zhí)行帶輸出參數的組合sql

declare @Dsql nvarchar(1000),
  @Name varchar(50),
  @TablePrimary varchar(50),
  @TableName varchar(50),
  @ASC int

 set @TablePrimary='ID';
 set @TableName='fine';
 set @ASC = 1;

 set @Dsql =N'select @Name = '+@TablePrimary+N' from '+@TableName+N' order by '+@TablePrimary+ (case @ASC when '1' then N' DESC ' ELSE N' ASC ' END)
print @Dsql

Set Rowcount 7
    exec sp_executesql @Dsql,N'@Name varchar(50) output',@Name output
print @Name
Set Rowcount 0

2、執(zhí)行帶輸入參數的組合sql

DECLARE @IntVariable INT
DECLARE @SQLString NVARCHAR(500)
DECLARE @ParmDefinition NVARCHAR(500)

/* Build the SQL string once. */
SET @SQLString =
   N'SELECT * FROM pubs.dbo.employee WHERE job_lvl = @level'
/* Specify the parameter format once. */
SET @ParmDefinition = N'@level tinyint'

/* Execute the string with the first parameter value. */
SET @IntVariable = 35
EXECUTE sp_executesql @SQLString, @ParmDefinition,
           @level = @IntVariable
/* Execute the same string with the second parameter value. */
SET @IntVariable = 32
EXECUTE sp_executesql @SQLString, @ParmDefinition,
           @level = @IntVariable