快捷導(dǎo)航

用VBS精確計(jì)算100的階乘的實(shí)現(xiàn)代碼

更新時(shí)間：2011年04月12日 15:46:11 作者：

運(yùn)行一下上面的程序，輸出2.43290200817664E+18。笑而不語(yǔ)，再次證明了我之前的結(jié)論，在這種網(wǎng)站上回答問(wèn)題的，大部分水平都不咋地。

今天又無(wú)聊的逛了一下搜搜問(wèn)問(wèn)，找到這樣一個(gè)問(wèn)題：

有誰(shuí)能提供vbs里20的階乘的詳細(xì)程序

下面有人給出了這樣的答案：

 
function jx(x) 
j=1 
for i=2 to x 
j=j*i 
next 
jx=j 
end function 
msgbox jx(20) 

運(yùn)行一下上面的程序，輸出2.43290200817664E+18。笑而不語(yǔ)，再次證明了我之前的結(jié)論，在這種網(wǎng)站上回答問(wèn)題的，大部分水平都不咋地。

其實(shí)之前在《用VBS精確計(jì)算2的100次方》我已經(jīng)寫(xiě)過(guò)了VBS的大數(shù)乘法，調(diào)用一下就行了：

復(fù)制代碼代碼如下:

 
'Author: Demon 
'Website: http://demon.tw 
'Email: 380401911@qq.com 
Option Explicit 
Function multiple(byVal x, byVal y) 
Dim n, t, i, j, z, w() 
n = Len(x) - 1 
t = Len(y) - 1 
ReDim w(n + t + 1) 
x = CStr(x) : y = CStr(y) 
For i = 0 To UBound(w) 
w(i) = "0" 
Next 
For i = 0 To t 
Dim c : c = 0 
Dim uv : uv = 0 
For j = 0 To n 
uv = (w(i+j)-"0") + c + _ 
(Mid(x,n-j+1,1)-"0") * (Mid(y,t-i+1,1)-"0") 
w(i+j) = CStr(uv Mod 10 + "0") 
c = uv \ 10 
Next 
w(i+n+1) = CStr(uv \ 10 + "0") 
Next 
z = Join(w,"") 
z = StrReverse(z) 
Do While Left(z,1) = "0" 
z = Mid(z,2) 
Loop 
multiple = z 
End Function 
Function factorial(n) 
Dim i, t : t = 1 
For i = 1 To n 
t = multiple(t, i) 
Next 
factorial = t 
End Function 
Dim t : t = Timer 
WScript.Echo factorial(100) 
WScript.Echo Timer - t 

另外，dogfish也寫(xiě)了一個(gè)求1000階乘的VBS：

復(fù)制代碼代碼如下:

 
dim digits(2568) 
max_digit = 2568 
digits(max_digit) = 1 
for d=2 to 1000 
for k=max_digit to ubound(digits) 
digits(k) = digits(k) *d 
next 
k = ubound(digits) 
while k>=max_digit 
if digits(k)>10 then 
digits(k-1) = digits(k-1) + fix(digits(k) / 10) 
digits(k) = digits(k) mod 10 
if k-1<max_digit then 
max_digit = k - 1 
end if 
end if 
k = k-1 
wend 
next 
'把結(jié)果轉(zhuǎn)為字串。 
str = "" 
for i=max_digit to ubound(digits) 
str = str & digits(i) 
next 
msgbox str 