修改文件名的批處理代碼

更新時間：2010年09月14日 09:09:58 投稿：mdxy-dxy

批處理：文件名修改，需要批量修改文件名的朋友可以參考下。

實例1

@echo off & setlocal enabledelayedexpansion 
echo -==文件名稱替換(去除文件名中的_v2和_V3)==- 
echo. 
echo. 

set /p folder=請輸入一個路徑: 

for /r %folder% %%i in (*) do ( 
set file=%%i 
set file=!file:_v2=! 
set file=!file:_v3=! 
if %%i neq !file! (move "%%i" "!file!") 
) 

echo. 
echo. 
echo 全部文件名替換完成。 
echo 按任意鍵退出。 
pause>nul

實例2 批處理替換修改文件名

當你有很多類似的文件，文件名可以很規(guī)律卻又有些不規(guī)律的時候...可以試試這個批處理。

@echo off
echo.&echo.
title 批量替換文件名中的部分字符串&color 3f
echo Note：
echo 本批處理可批量替換本文件所在文件夾下的所有文件名的相同字符
echo.&echo.&echo.&echo.&echo.&echo.
echo.&set /p strtemp3= 請輸入要替換的文件類型：
echo.&set /p strtemp1= 請輸入要替換的字符串（可替換空格）：
echo.&set /p strtemp2= 請輸入替換后的字符串（刪除則直接回車）：
setlocal enabledelayedexpansion
for /f "delims=" %%a in ('dir /a /b *.%strtemp3%') do (
set nobird=%%a
ren "%%~a" "!nobird:%strtemp1%=%strtemp2%!")
echo.&echo.&echo.&echo.&echo Done！
pause

批處理重命名為按數字增加的實現代碼

1.將要重命名的文件集體選擇右擊重命名為非數字的名稱
2.將此命令保存成bat放在要重命名的目錄下，名字改為demo.bat (或自行改成其他，代碼跟著更改)

@echo off
setlocal enabledelayedexpansion
for %%x in (*) do (
  if not "%%x"=="demo.bat" (
    set /a sum+=1
    rename "%%x" "!sum!.txt"
   
)
)
echo 批量重命名完成！
pause

3.更改不同的后綴名根據自己需要更改

批處理命令實現文件規(guī)范重命名

平時較少利用批處理命令，通過網絡學習實現該功能，分享給需要的朋友。

實現批處理所在文件夾下指定后綴名(如本例JPG)的全部文件(不包括子文件夾)的名字為規(guī)范的文件名。

@echo off&setlocal EnableDelayedExpansion 
set a=0
for /f "delims=" %%i in ('dir /b *.jpg') do ( 
if not "%%~ni"=="%~n0" ( 
if !a! LSS 10 (
ren "%%i" "sample0000!a!.jpg")else if !a! LSS 100 (
ren "%%i" "sample000!a!.jpg")else if !a! LSS 1000 (
ren "%%i" "sample00!a!.jpg")else if !a! LSS 10000 (
ren "%%i" "sample0!a!.jpg")else (
ren "%%i" "sample!a!.jpg")
set/a a+=1 
) 
)

以上就是修改文件名的批處理代碼的詳細內容，更多關于文件名修改的資料請關注腳本之家其它相關文章！

您可能感興趣的文章: