Oracle在DML語句中使用returing?into子句

更新時間：2022年05月06日 09:48:12 作者：springsnow

這篇文章介紹了Oracle在DML語句中使用returing?into子句的方法，文中通過示例代碼介紹的非常詳細。對大家的學(xué)習(xí)或工作具有一定的參考借鑒價值，需要的朋友可以參考下

一、概述：

ORACLE的DML語句中可以指定RETURNING語句。使用起來也很簡單，和SELECT INTO語句沒有多大區(qū)別。RETURNING語句的使用在很多情況下可以簡化PL/SQL編程。

INSERT操作：返回INSERT之后的結(jié)果；
UPDATE操作：返回UPDATE操作之后的結(jié)果。
DELETE操作：返回DELETE之前的結(jié)果；

INSERT INTO SELECT和MERGE語句不支持RETURNING語句。RETURNING和return通用。

二、當(dāng)插入使用序列生成主鍵值的數(shù)據(jù)時，能返回此主鍵值。

DECLARE
  l_id t1.id%TYPE;
BEGIN
  INSERT INTO t1 VALUES (t1_seq.nextval, 'FOUR')
  RETURNING id INTO l_id;
  COMMIT;

  DBMS_OUTPUT.put_line('ID=' || l_id);
END;

三、更新和刪除語句。

DECLARE
  l_id t1.id%TYPE;
BEGIN
  UPDATE t1  SET    description = description  WHERE  description = 'FOUR'
  RETURNING id INTO l_id;

  DBMS_OUTPUT.put_line('UPDATE ID=' || l_id);

  DELETE FROM t1  WHERE  description = 'FOUR'
  RETURNING id INTO l_id;

  DBMS_OUTPUT.put_line('DELETE ID=' || l_id);

  COMMIT;

四、當(dāng)DML影響多行時，使用returing into，借助bulk collection語句將值返回到一個集合中。

DECLARE
  TYPE t_tab IS TABLE OF t1.id%TYPE;
  l_tab t_tab;
BEGIN
  UPDATE t1  SET    description = description
  RETURNING id BULK COLLECT INTO l_tab;

  FOR i IN l_tab.first .. l_tab.last LOOP
    DBMS_OUTPUT.put_line('UPDATE ID=' || l_tab(i));
  END LOOP;

  COMMIT;
END;

五、在For All語句中使用returing into。

DECLARE
  TYPE t_desc_tab IS TABLE OF t1.description%TYPE;
  TYPE t_tab IS TABLE OF t1%ROWTYPE;
  l_desc_tab t_desc_tab := t_desc_tab('FIVE', 'SIX', 'SEVEN');
  l_tab   t_tab;
BEGIN  
  FORALL i IN l_desc_tab.first .. l_desc_tab.last
    INSERT INTO t1 VALUES (t1_seq.nextval, l_desc_tab(i))
    RETURNING id, description BULK COLLECT INTO l_tab;

  FOR i IN l_tab.first .. l_tab.last LOOP
    DBMS_OUTPUT.put_line('INSERT ID=' || l_tab(i).id ||    ' DESC=' || l_tab(i).description);
  END LOOP;

  COMMIT;
END;

六、在動態(tài)sql中使用。

DECLARE
  TYPE t_tab IS TABLE OF t1.id%TYPE;
  l_tab t_tab;
BEGIN
  EXECUTE IMMEDIATE 'UPDATE t1 SET  description = description   RETURNING id INTO :l_tab'
  using 7369
  RETURNING BULK COLLECT INTO l_tab;

  FOR i IN l_tab.first .. l_tab.last LOOP
    DBMS_OUTPUT.put_line('UPDATE ID=' || l_tab(i));
  END LOOP;

  COMMIT;
END;

注意：

returning into在動態(tài)sql內(nèi)部和外面都要寫，且外面的returning后面不加字段直接into。
using在returning前面
動態(tài)sql內(nèi)部into后面變量名不固定，注意冒號(:)，可以是命名規(guī)則下的任意字符。
returning bulk collect into要寫在外面，且后面不能是record。

七、在C# 中使用returing into子句。

using (OracleCommand cmd = Globals.Db.Connection.CreateCommand())
{
    cmd.CommandText = "INSERT INTO table (Col1, Col2) VALUES (:ParamCol1, :ParamCol2) RETURNING ROWIDTOCHAR(ROWID) INTO :OutputROWID";
    cmd.Parameters.Add(paramCol1, data["Col1"]);
    cmd.Parameters.Add(paramCol2, data["Col2"]);
    OracleParameter outputRowId = new OracleParameter(":OutputROWID", OracleDbType.Varchar2, 30)
    {
        Direction = ParameterDirection.ReturnValue
    };//一定要有Size參數(shù)。
    cmd.Parameters.Add(outputRowId);
    cmd.BindByName = true;

    cmd.ExecuteNonQuery();
    string rtnValue = outputRowId.Value.ToString();
}

到此這篇關(guān)于Oracle在DML語句中使用returing into子句的文章就介紹到這了。希望對大家的學(xué)習(xí)有所幫助，也希望大家多多支持腳本之家。

您可能感興趣的文章: