//1.setting.gradle 執(zhí)行結(jié)束的監(jiān)聽
gradle.settingsEvaluated {
    println "settings.gradle 初始化執(zhí)行結(jié)束"
}

//2.參與構(gòu)建的Project對(duì)象創(chuàng)建完畢的監(jiān)聽
gradle.projectsLoaded {
    Gradle gradle ->
        println "settings.gradle 所有在 settings 中 include 的 Project 都創(chuàng)建完成了"
}

gradle.beforeProject {
    Project project ->
        println ">>>>>>>>gradle beforeProject " + project.name + " 配置開始前回調(diào)"
}

this.afterEvaluate {
    project ->
        println project.name + " 配置結(jié)束監(jiān)聽"
}

gradle.projectsEvaluated {
    gradle ->
        println "所有的project都配置完畢了，準(zhǔn)備生成Task依賴關(guān)系"
}

gradle.taskGraph.whenReady {
    TaskExecutionGraph graph ->
        println "task 依賴關(guān)系已經(jīng)生成"
}

gradle.taskGraph.beforeTask {
    Task task ->
        println "Project[${task.project.name}]--->Task[${task.name}] 在執(zhí)行之前被回調(diào)"
}

gradle.taskGraph.afterTask {
    task, TaskState taskState ->
        //第二個(gè)參數(shù)表示 task 的狀態(tài)，是可選的參數(shù)
        println "Project[${task.project.name}]--->Task[${task.name}] 在執(zhí)行完畢,taskState[upToDate:${taskState.upToDate},skipped:${taskState.skipped},executed:${taskState.executed},didWork:${taskState.didWork}]"
}

gradle.buildFinished {
    BuildResult buildResult ->
        println "構(gòu)建完畢"
}

//配置 app module
project(":app") {
    Project project ->
        project.afterEvaluate {
            //獲取build task 任務(wù)
            Task buildTask = getBuildTask(project, ":app:build")
            //獲取 preBuild 任務(wù)
            Task preBuildTask = getBuildTask(project, ":app:preBuild")

            def taskStartTime = 0
            def taskEndTime = 0

            //在preBuild task 中追加一個(gè)監(jiān)聽獲取在preBuild執(zhí)行之前的時(shí)間戳的 action 
            preBuildTask.doFirst {
                taskStartTime = System.currentTimeMillis()
            }
            //在build task 中追加一個(gè)監(jiān)聽獲取執(zhí)行完畢的時(shí)間戳的 action 
            buildTask.doLast {
                taskEndTime = System.currentTimeMillis()
                println "build task 執(zhí)行時(shí)間：${taskEndTime - taskStartTime}"
            }
        }
}

/**
 * 獲取該project對(duì)應(yīng)的build任務(wù)
 * @param project
 * @return
 */
Task getBuildTask(Project project, String taskPath) {

    //獲取該project管理task的容器
    TaskContainer taskContainer = project.getTasks()

    //拿到build的Task對(duì)象
    Task buildTask = taskContainer.getByPath(taskPath)

    return buildTask
}