快捷導(dǎo)航

10分鐘搞定讓你困惑的 Jenkins 環(huán)境變量過程詳解

更新時(shí)間：2021年01月08日 09:41:39 作者：日拱一兵

這篇文章主要介紹了10分鐘搞定讓你困惑的 Jenkins 環(huán)境變量過程詳解,本文通過圖文實(shí)例相結(jié)合給大家介紹的非常詳細(xì)，對(duì)大家的學(xué)習(xí)或工作具有一定的參考借鑒價(jià)值，需要的朋友可以參考下

前言

Jenkins， DevOps 技術(shù)棧的核心之一，CI/CD 離不開編寫 Pipeline 腳本，上手 Jenkins ，簡(jiǎn)單查一下文檔，你就應(yīng)該不會(huì)被 agent，stages，step 這類關(guān)鍵詞弄懵，也能很快構(gòu)建出 pipeline 的骨架

但是當(dāng)向骨架中填充內(nèi)容的時(shí)候，尤其如何利用環(huán)境變量（系統(tǒng)內(nèi)置｜自定義），多數(shù)人都會(huì)變得比較混亂，浪費(fèi)很多時(shí)間，本文就幫助大家快速通關(guān)環(huán)境變量

準(zhǔn)備

如果你想一邊閱讀本文，一邊實(shí)踐，但是沒有 Jenkins 服務(wù)可用，又想快速嘗試，可以應(yīng)用 Docker 一個(gè)命令快速搭建 Jenkins 服務(wù)

docker container run --rm -p 8080:8080 -p 50000:50000 --name=jenkins -v $(pwd):/var/jenkins_home jenkins/jenkins

2021 年了，本地沒有 Docker 說不過去了，過來瞧瞧 Docker 系列是否入得了你的法眼？

打開瀏覽器輸入：localhost:8080

找到終端的臨時(shí)密碼登陸
安裝推薦的依賴
創(chuàng)建新的 Pipeline 類型的 Item
點(diǎn)擊左側(cè) Config，然后在頁面底部 Pipeline 部分輸入我們接下來寫的腳本進(jìn)行測(cè)試就好了

就是這么簡(jiǎn)單.....

認(rèn)識(shí) Jenkins 環(huán)境變量

Jenkins 環(huán)境變量就是通過 env 關(guān)鍵字暴露出來的全局變量，可以在 Jenkins 文件的任何位置使用

其實(shí)和你使用的編程語言中的全局變量沒有實(shí)質(zhì)差別

查看 Jenkins 系統(tǒng)內(nèi)置環(huán)境變量

Jenkins 在系統(tǒng)內(nèi)置了很多環(huán)境變量方便我們快速使用，查看起來有兩種方式：

方式一：

直接在瀏覽器中訪問 ${YOUR_JENKINS_HOST}/env-vars.html 頁面就可以，比如 http://localhost:8080/env-vars.html ，每個(gè)變量的用途寫的都很清楚

方式二

通過執(zhí)行 printenv shell 命令來獲取：

pipeline {
  agent any

  stages {
    stage("Env Variables") {
      steps {
        sh "printenv"
      }
    }
  }
}

直接 Save - Build, 在終端 log 中你會(huì)看到相應(yīng)的環(huán)境變量，并且可以快速看到他們當(dāng)前的值

通常這兩種方式可以結(jié)合使用

讀取環(huán)境變量

上面我們說了 env 是環(huán)境變量的關(guān)鍵字，但是讀取 Jenkins 內(nèi)置的這些環(huán)境變量，env 關(guān)鍵字是可有可無, 但不能沒了底褲，都要使用 ${xxx} 包圍起來。以 BUILD_NUMBER 這個(gè)內(nèi)置環(huán)境變量舉例來說明就是這樣滴：

如果你在 Jenkins 文件中使用 shell 命令，使用這些內(nèi)置環(huán)境變量甚至可以不用 {}，來看一下：

pipeline {
  agent any

  stages {
    stage("Read Env Variables") {
      steps {
        echo "帶 env 的讀取方式：${env.BUILD_NUMBER}"
        echo "不帶 env 的讀取方式：${BUILD_NUMBER}"
        sh 'echo "shell 中讀取方式 $BUILD_NUMBER"'
      }
    }
  }
}

可以看到結(jié)果是一樣一樣滴，不管有幾種，記住第一種最穩(wěn)妥

內(nèi)置的環(huán)境變量雖好，但也不能完全滿足我們自定義的 pipeline 的執(zhí)行邏輯，所以我們也得知道如何定義以及使用自定義環(huán)境變量

自定義 Jenkins 環(huán)境變量

Jenkins pipeline 分聲明式（Declarative）和腳本式（imperative）寫法，相應(yīng)的環(huán)境變量定義方式也略有不同，歸納起來有三種方式：

還是看個(gè)實(shí)際例子吧：

pipeline {
  agent any

  environment {
    FOO = "bar"
  }

  stages {
    stage("Custom Env Variables") {
      environment {
        NAME = "RGYB"
      }

      steps {
        echo "FOO = ${env.FOO}"
        echo "NAME = ${env.NAME}"

        script {
          env.SCRIPT_VARIABLE = "Thumb Up"
        }

        echo "SCRIPT_VARIABLE = ${env.SCRIPT_VARIABLE}"

        withEnv(["WITH_ENV_VAR=Come On"]) {
          echo "WITH_ENV_VAR = ${env.WITH_ENV_VAR}"
        }
      }
    }
  }
}

來看運(yùn)行結(jié)果：

注意：withEnv(["WITH_ENV_VAR=Come On"]) {} 這里的 = 號(hào)兩側(cè)不能有空格，必須是 key=value 的形式

一個(gè)完整的 pipeline 通常會(huì)有很多個(gè) stage，環(huán)境變量在不同的 stage 有不同的值是很常見的，知道如何設(shè)置以及讀取環(huán)境變量后，我們還得知道如何重寫環(huán)境變量

重寫 Jenkins 環(huán)境變量

Jenkins 讓人相對(duì)困惑最多的地方就是重寫環(huán)境變量，但是只要記住下面這三條規(guī)則，就可以搞定一切了

withEnv(["WITH_ENV_VAR=Come On"]) {} 內(nèi)置函數(shù)的這種寫法，可以重寫任意環(huán)境變量
定義在 environment {} 的環(huán)境變量不能被腳本式定義的環(huán)境變量（env.key="value"）重寫
腳本式環(huán)境變量只能重寫腳本式環(huán)境變量

這三點(diǎn)是硬規(guī)則，沒涵蓋在這 3 點(diǎn)規(guī)則之內(nèi)的也就是被允許的了

三條規(guī)則就有點(diǎn)讓人頭大了，農(nóng)夫選豆種，舉例為證吧

pipeline {
  agent any

  environment {
    FOO = "你當(dāng)像鳥飛往你的山"
    NAME = "Tan"
  }

  stages {
    stage("Env Variables") {
      environment {
       	// 會(huì)重寫第 6 行 變量
        NAME = "RGYB" 
       	// 會(huì)重寫系統(tǒng)內(nèi)置的環(huán)境變量 BUILD_NUMBER
        BUILD_NUMBER = "10" 
      }

      steps {
       	// 應(yīng)該打印出 "FOO = 你當(dāng)像鳥飛往你的山"
        echo "FOO = ${env.FOO}" 
       	// 應(yīng)該打印出 "NAME = RGYB"
        echo "NAME = ${env.NAME}" 
       	// 應(yīng)該打印出 "BUILD_NUMBER = 10"
        echo "BUILD_NUMBER = ${env.BUILD_NUMBER}" 

        script {
         	// 腳本式創(chuàng)建一個(gè)環(huán)境變量
          env.SCRIPT_VARIABLE = "1" 
        }
      }
    }

    stage("Override Variables") {
      steps {
        script {
         	// 這里的 FOO 不會(huì)被重寫，違背 Rule No.2
          env.FOO = "Tara"
         	// SCRIPT_VARIABLE 變量會(huì)被重寫，符合 Rule No.3
          env.SCRIPT_VARIABLE = "2" 
        }

       	// FOO 在第 37 行重寫失敗，還會(huì)打印出 "FOO = 你當(dāng)像鳥飛往你的山"
        echo "FOO = ${env.FOO}" 
       	// 會(huì)打印出 "SCRIPT_VARIABLE = 2"
        echo "SCRIPT_VARIABLE = ${env.SCRIPT_VARIABLE}" 

       	// FOO 會(huì)被重寫，符合 Rule No.1
        withEnv(["FOO=Educated"]) { 
         	// 應(yīng)該打印 "FOO = Educated"
          echo "FOO = ${env.FOO}" 
        }

       	// 道理同上
        withEnv(["BUILD_NUMBER=15"]) {
         	// 應(yīng)該打印出 "BUILD_NUMBER = 15"
          echo "BUILD_NUMBER = ${env.BUILD_NUMBER}"
        }
      }
    }
  }
}

來驗(yàn)證一下結(jié)果吧

看到這，基本的設(shè)置應(yīng)該就沒有什么問題了，相信你也發(fā)現(xiàn)了，Jenkins 設(shè)置環(huán)境變量和編程語言的那種設(shè)置環(huán)境變量還是略有不同的，后者可以將變量賦值為對(duì)象，但 Jenkins 就不行，因?yàn)樵?Jenkins 文件中，所有設(shè)置的值都會(huì)被當(dāng)成 String，難道沒辦法應(yīng)用 Boolean 值嗎？

Jenkins 中使用 Boolean 值

如果設(shè)置一個(gè)變量為 false ，Jenkins 就會(huì)將其轉(zhuǎn)換為 "false", 如果想使用 Boolean 來做條件判斷，必須要調(diào)用 toBoolean() 方法做轉(zhuǎn)換

pipeline {
  agent any

  environment {
    IS_BOOLEAN = false
  }

  stages {
    stage("Env Variables") {
      steps {
        script {
         	// Hello 會(huì)被打印出來，因?yàn)榉强兆址紩?huì)被認(rèn)為是 Boolean.True
          if (env.IS_BOOLEAN) {
            echo "Hello"
          }

         	// 真正的 Boolean 比較
          if (env.IS_BOOLEAN.toBoolean() == false) {
            echo "日拱一兵"
          }
         
         	// 真正的 Boolean 
          if (!env.IS_BOOLEAN.toBoolean()) {
            echo "RGYB"
          }
        }
      }
    }
  }
}

來看運(yùn)行結(jié)果：

如果你寫過 Pipeline，你一定會(huì)知道，寫 Pipeline 是離不開寫 shell 的，有些時(shí)候，需要將 shell 的執(zhí)行結(jié)果賦值給環(huán)境變量，Jenkins 也有方法支持

Shell 結(jié)果賦值給環(huán)境變量

實(shí)現(xiàn)這種方式很簡(jiǎn)單，只需要記住一個(gè)格式：sh(script: 'cmd', returnStdout:true)

pipeline {
  agent any

  environment {
   	// 使用 trim() 去掉結(jié)果中的空格
    LS_RESULT = "${sh(script:'ls -lah', returnStdout: true).trim()}"
  }

  stages {
    stage("Env Variables") {
      steps {
        echo "LS_RESULT = ${env.LS_RESULT}"
      }
    }
  }
}