python 實現(xiàn)非極大值抑制算法（Non-maximum suppression, NMS）

更新時間：2020年10月15日 09:59:19 作者：農(nóng)大魯迅

這篇文章主要介紹了python 如何實現(xiàn)非極大值抑制算法（Non-maximum suppression, NMS），幫助大家更好的進(jìn)行機(jī)器學(xué)習(xí)，感興趣的朋友可以了解下

NMS 算法在目標(biāo)檢測，目標(biāo)定位領(lǐng)域有較廣泛的應(yīng)用。

算法原理

非極大值抑制算法（Non-maximum suppression, NMS）的本質(zhì)是搜索局部極大值，抑制非極大值元素。

算法的作用

當(dāng)算法對一個目標(biāo)產(chǎn)生了多個候選框的時候，選擇 score 最高的框，并抑制其他對于改目標(biāo)的候選框

適用場景

一幅圖中有多個目標(biāo)（如果只有一個目標(biāo)，那么直接取 score 最高的候選框即可）。

算法的輸入

算法對一幅圖產(chǎn)生的所有的候選框，以及每個框?qū)?yīng)的 score （可以用一個 5 維數(shù)組 dets 表示，前 4 維表示四個角的坐標(biāo)，第 5 維表示分?jǐn)?shù)），閾值 thresh。

算法的輸出

正確的候選框組（dets 的一個子集）。

細(xì)節(jié)

起始，設(shè)所有的框都沒有被抑制，所有框按照 score 從大到小排序。
從第 0 個框（分?jǐn)?shù)最高）開始遍歷：對于每一個框，如果該框沒有被抑制，就將所有與它 IoU 大于 thresh 的框設(shè)為抑制。
返回沒被抑制的框。

參考代碼

# --------------------------------------------------------
# Fast R-CNN
# Copyright (c) 2015 Microsoft
# Licensed under The MIT License [see LICENSE for details]
# Written by Ross Girshick
# --------------------------------------------------------

import numpy as np
cimport numpy as np

cdef inline np.float32_t max(np.float32_t a, np.float32_t b):
  return a if a >= b else b

cdef inline np.float32_t min(np.float32_t a, np.float32_t b):
  return a if a <= b else b

def cpu_nms(np.ndarray[np.float32_t, ndim=2] dets, np.float thresh):
  cdef np.ndarray[np.float32_t, ndim=1] x1 = dets[:, 0]
  cdef np.ndarray[np.float32_t, ndim=1] y1 = dets[:, 1]
  cdef np.ndarray[np.float32_t, ndim=1] x2 = dets[:, 2]
  cdef np.ndarray[np.float32_t, ndim=1] y2 = dets[:, 3]
  cdef np.ndarray[np.float32_t, ndim=1] scores = dets[:, 4]

  cdef np.ndarray[np.float32_t, ndim=1] areas = (x2 - x1 + 1) * (y2 - y1 + 1)
  cdef np.ndarray[np.int_t, ndim=1] order = scores.argsort()[::-1]

  cdef int ndets = dets.shape[0]
  cdef np.ndarray[np.int_t, ndim=1] suppressed = \
      np.zeros((ndets), dtype=np.int)

  # nominal indices
  cdef int _i, _j
  # sorted indices
  cdef int i, j
  # temp variables for box i's (the box currently under consideration)
  cdef np.float32_t ix1, iy1, ix2, iy2, iarea
  # variables for computing overlap with box j (lower scoring box)
  cdef np.float32_t xx1, yy1, xx2, yy2
  cdef np.float32_t w, h
  cdef np.float32_t inter, ovr

  keep = []
  for _i in range(ndets):
    i = order[_i]
    if suppressed[i] == 1:
      continue
    keep.append(i)
    ix1 = x1[i]
    iy1 = y1[i]
    ix2 = x2[i]
    iy2 = y2[i]
    iarea = areas[i]
    for _j in range(_i + 1, ndets):
      j = order[_j]
      if suppressed[j] == 1:
        continue
      xx1 = max(ix1, x1[j])
      yy1 = max(iy1, y1[j])
      xx2 = min(ix2, x2[j])
      yy2 = min(iy2, y2[j])
      w = max(0.0, xx2 - xx1 + 1)
      h = max(0.0, yy2 - yy1 + 1)
      inter = w * h
      ovr = inter / (iarea + areas[j] - inter)
      if ovr >= thresh:
        suppressed[j] = 1

  return keep

以上就是python 實現(xiàn)非極大值抑制算法（Non-maximum suppression, NMS）的詳細(xì)內(nèi)容，更多關(guān)于python 非極大值抑制算法的資料請關(guān)注腳本之家其它相關(guān)文章！

您可能感興趣的文章: