快捷導(dǎo)航

Unity Shader實(shí)現(xiàn)新手引導(dǎo)遮罩鏤空效果

更新時(shí)間：2020年02月13日 09:53:52 作者：mac_zly

這篇文章主要為大家詳細(xì)介紹了Unity Shader實(shí)現(xiàn)新手引導(dǎo)遮罩鏤空效果，文中示例代碼介紹的非常詳細(xì)，具有一定的參考價(jià)值，感興趣的小伙伴們可以參考一下

這兩天實(shí)現(xiàn)了下新手引導(dǎo)需要的遮罩鏤空shader效果，記錄一下。

1、圓形鏤空shader代碼：

//計(jì)算片元世界坐標(biāo)和目標(biāo)中心位置的距離
float dis = distance(IN.worldPosition.xy, _Center.xy);
//過(guò)濾掉距離小于（半徑-過(guò)渡范圍）的片元
clip(dis - (_Radius - _TransitionRange));
//優(yōu)化if條件判斷，如果距離小于半徑則執(zhí)行下一步，等于if(dis < _Radius)
fixed tmp = step(dis, _Radius);
//計(jì)算過(guò)渡范圍內(nèi)的alpha值
color.a *= (1 - tmp) + tmp * (dis - (_Radius - _TransitionRange)) / _TransitionRange;

效果：忽略漸變的蒙版，隨便找的圖片

2、橢圓鏤空shader代碼：

//計(jì)算X軸方向距離
float disX = distance(IN.worldPosition.x, _Center.x);
//計(jì)算Y軸方向距離
float disY = distance(IN.worldPosition.y, _Center.y);
//運(yùn)用橢圓方程計(jì)算片元的alpha值，_Ellipse為橢圓系數(shù)
fixed factor = clamp(pow(abs(disX / _Width), _Ellipse) + pow(abs(disY / _Height), _Ellipse), 0.0, 1.0);
//優(yōu)化if條件判斷
fixed tmp = step(factor, 1.0f);
//賦值橢圓外或橢圓內(nèi)的alpha值
color.a *= (1 - tmp) + tmp * factor;

效果：

3、圓形目標(biāo)位置聚合動(dòng)畫(huà)shader代碼：

//_StartTime為效果開(kāi)始時(shí)間點(diǎn)，Unity中對(duì)應(yīng)賦值material.SetFloat("_StartTime", Time.timeSinceLevelLoad);
fixed processTime = _Time.y - _StartTime;
//判斷shader執(zhí)行時(shí)長(zhǎng)是否超過(guò)_TotalTime
clip(_TotalTime - processTime);
//優(yōu)化if條件判斷
fixed tmp = step(processTime, _ReduceTime);
//計(jì)算當(dāng)前時(shí)間點(diǎn)的圓形鏤空半徑
float curRadius = (1 - tmp) * _Radius + tmp * (_MaxRadius - (_MaxRadius - _Radius) * processTime / _ReduceTime);
float dis = distance(IN.worldPosition.xy, _Center.xy);
//拋棄距離小于當(dāng)前圓形鏤空半徑的片元
clip(dis - curRadius);

效果：不知道為啥上傳上來(lái)就有問(wèn)題了，正常是沒(méi)問(wèn)題的

整個(gè)shader源碼，在Unity UGUI 自帶Default shader基礎(chǔ)上添加：

// Unity built-in shader source. Copyright (c) 2016 Unity Technologies. MIT license (see license.txt)

Shader "UI/Default_Mask"
{
  Properties
  {
    [PerRendererData] _MainTex ("Sprite Texture", 2D) = "white" {}
    _Color ("Tint", Color) = (1,1,1,1)

    _StencilComp ("Stencil Comparison", Float) = 8
    _Stencil ("Stencil ID", Float) = 0
    _StencilOp ("Stencil Operation", Float) = 0
    _StencilWriteMask ("Stencil Write Mask", Float) = 255
    _StencilReadMask ("Stencil Read Mask", Float) = 255

    _ColorMask ("Color Mask", Float) = 15

    [Toggle(UNITY_UI_ALPHACLIP)] _UseUIAlphaClip ("Use Alpha Clip", Float) = 0
 //-------------------add----------------------
 _Center("Center", vector) = (0, 0, 0, 0)
 _Radius("Radius", Range(0,1000)) = 1000 // sliders
 _TransitionRange("Transition Range", Range(0, 100)) = 10
 _Width("Width", Float) = 1
 _Height("Height", Float) = 1
 _Ellipse("Ellipse", Float) = 4
 _ReduceTime("ReduceTime", Float) = 1
 _TotalTime("TotalTime", Float) = 1
 _StartTime("StartTime", Float) = 0
 _MaxRadius("MaxRadius", Float) = 1500
 [KeywordEnum(ROUND, ELLIPSE, DYNAMIC_ROUND)] _RoundMode("Mask mode", Float) = 0
 //-------------------add----------------------
  }

  SubShader
  {
    Tags
    {
      "Queue"="Transparent"
      "IgnoreProjector"="True"
      "RenderType"="Transparent"
      "PreviewType"="Plane"
      "CanUseSpriteAtlas"="True"
    }

    Stencil
    {
      Ref [_Stencil]
      Comp [_StencilComp]
      Pass [_StencilOp]
      ReadMask [_StencilReadMask]
      WriteMask [_StencilWriteMask]
    }

    Cull Off
    Lighting Off
    ZWrite Off
    ZTest [unity_GUIZTestMode]
    Blend SrcAlpha OneMinusSrcAlpha
    ColorMask [_ColorMask]

    Pass
    {
      Name "Default"
    CGPROGRAM
      #pragma vertex vert
      #pragma fragment frag
      #pragma target 2.0

      #include "UnityCG.cginc"
      #include "UnityUI.cginc"

      #pragma multi_compile __ UNITY_UI_CLIP_RECT
      #pragma multi_compile __ UNITY_UI_ALPHACLIP
  #pragma multi_compile _ROUNDMODE_ROUND _ROUNDMODE_ELLIPSE _ROUNDMODE_DYNAMIC_ROUND

      struct appdata_t
      {
        float4 vertex  : POSITION;
        float4 color  : COLOR;
        float2 texcoord : TEXCOORD0;
        UNITY_VERTEX_INPUT_INSTANCE_ID
      };

      struct v2f
      {
        float4 vertex  : SV_POSITION;
        fixed4 color  : COLOR;
        float2 texcoord : TEXCOORD0;
        float4 worldPosition : TEXCOORD1;
        UNITY_VERTEX_OUTPUT_STEREO
      };

      fixed4 _Color;
      fixed4 _TextureSampleAdd;
      float4 _ClipRect;
  //-------------------add----------------------
  half _Radius;
  float2 _Center;
  half _TransitionRange;
  half _Width;
  half _Height;
  half _Ellipse;
  fixed _ReduceTime;
  half _TotalTime;
  float _StartTime;
  half _MaxRadius;

  //-------------------add----------------------

      v2f vert(appdata_t v)
      {
        v2f OUT;
        UNITY_SETUP_INSTANCE_ID(v);
        UNITY_INITIALIZE_VERTEX_OUTPUT_STEREO(OUT);
        OUT.worldPosition = v.vertex;
        OUT.vertex = UnityObjectToClipPos(OUT.worldPosition);

        OUT.texcoord = v.texcoord;

        OUT.color = v.color * _Color;
        return OUT;
      }

      sampler2D _MainTex;

      fixed4 frag(v2f IN) : SV_Target
      {
        half4 color = (tex2D(_MainTex, IN.texcoord) + _TextureSampleAdd) * IN.color;

        #ifdef UNITY_UI_CLIP_RECT
        color.a *= UnityGet2DClipping(IN.worldPosition.xy, _ClipRect);
        #endif

        #ifdef UNITY_UI_ALPHACLIP
        clip (color.a - 0.001);
        #endif

  //-------------------add----------------------
#ifdef _ROUNDMODE_ROUND
  //計(jì)算片元世界坐標(biāo)和目標(biāo)中心位置的距離
  float dis = distance(IN.worldPosition.xy, _Center.xy);
  //過(guò)濾掉距離小于（半徑-過(guò)渡范圍）的片元
  clip(dis - (_Radius - _TransitionRange));
  //優(yōu)化if條件判斷，如果距離小于半徑則執(zhí)行下一步，等于if(dis < _Radius)
  fixed tmp = step(dis, _Radius);
  //計(jì)算過(guò)渡范圍內(nèi)的alpha值
  color.a *= (1 - tmp) + tmp * (dis - (_Radius - _TransitionRange)) / _TransitionRange;
#elif _ROUNDMODE_ELLIPSE
  //計(jì)算X軸方向距離
  float disX = distance(IN.worldPosition.x, _Center.x);
  //計(jì)算Y軸方向距離
  float disY = distance(IN.worldPosition.y, _Center.y);
  //運(yùn)用橢圓方程計(jì)算片元的alpha值，_Ellipse為橢圓系數(shù)
  fixed factor = clamp(pow(abs(disX / _Width), _Ellipse) + pow(abs(disY / _Height), _Ellipse), 0.0, 1.0);
  //優(yōu)化if條件判斷
  fixed tmp = step(factor, 1.0f);
  //賦值橢圓外或橢圓內(nèi)的alpha值
  color.a *= (1 - tmp) + tmp * factor;
#else
  //_StartTime為效果開(kāi)始時(shí)間點(diǎn)，Unity中對(duì)應(yīng)賦值material.SetFloat("_StartTime", Time.timeSinceLevelLoad);
  fixed processTime = _Time.y - _StartTime;
  //判斷shader執(zhí)行時(shí)長(zhǎng)是否超過(guò)_TotalTime
  clip(_TotalTime - processTime);
  //優(yōu)化if條件判斷
  fixed tmp = step(processTime, _ReduceTime);
  //計(jì)算當(dāng)前時(shí)間點(diǎn)的圓形鏤空半徑
  float curRadius = (1 - tmp) * _Radius + tmp * (_MaxRadius - (_MaxRadius - _Radius) * processTime / _ReduceTime);
  float dis = distance(IN.worldPosition.xy, _Center.xy);
  //拋棄距離小于當(dāng)前圓形鏤空半徑的片元
  clip(dis - curRadius);
#endif
  //-------------------add----------------------
        return color;
      }
    ENDCG
    }
  }
}

以上就是本文的全部?jī)?nèi)容，希望對(duì)大家的學(xué)習(xí)有所幫助，也希望大家多多支持腳本之家。

您可能感興趣的文章: