快捷導(dǎo)航

Transpose 數(shù)組行列轉(zhuǎn)置的限制方式

更新時間：2020年02月11日 13:05:01 投稿：jingxian

今天小編就為大家分享一篇Transpose 數(shù)組行列轉(zhuǎn)置的限制方式，具有很好的參考價值，希望對大家有所幫助。一起跟隨小編過來看看吧

提到數(shù)組，大家都不陌生，什么是數(shù)組行列轉(zhuǎn)置呢？其實也很簡單，如下圖所示，行列轉(zhuǎn)置就是將數(shù)組元素的存放方式進(jìn)行轉(zhuǎn)換，原來保存在第一列的數(shù)據(jù)，將保持在新數(shù)組的第一行，并且保持原有順序，即6在第一個位置，8在最后一個位置。其他列依次類推。

在Excel工作表中有個強(qiáng)大的函數(shù)Transpose，可以直接實現(xiàn)數(shù)組行列轉(zhuǎn)置，作為VBA開發(fā)者來說，肯定不會忘記用這個。

Sub Demo1()
  Dim aData(1 To 3, 1 To 2)
  For i = 1 To 3
    For j = 1 To 2
      aData(i, j) = i + j * 5
    Next j
  Next i
  aTrans = Application.Transpose(aData)
  Debug.Print UBound(aData, 1) & " x "; UBound(aData, 2)
  Debug.Print "=>>"
  Debug.Print UBound(aTrans, 1) & " x "; UBound(aTrans, 2)
End Sub

一句代碼輕松實現(xiàn)轉(zhuǎn)置，比很多程序開發(fā)語言都要簡單，在本地窗口中可以看到轉(zhuǎn)置效果。

這么好用的神奇代碼，有時會莫名其妙的罷工，我們來看看下面的代碼，運(yùn)行代碼將給出“類型不匹配”的錯誤提示，錯誤號為“13”。

Sub Demo2()
  Dim aData(1 To 3, 1 To 2)
  For i = 1 To 3
    For j = 1 To 2
      aData(i, j) = i + j * 5
    Next j
  Next i
  aData(1, 1) = Application.Rept("$", 256)
  aTrans = Application.Transpose(aData)  ' Runtime error "13"
  Debug.Print UBound(aData, 1) & " x "; UBound(aData, 2)
  Debug.Print "=>>"
  Debug.Print UBound(aTrans, 1) & " x "; UBound(aTrans, 2)
End Sub

轉(zhuǎn)置失敗的原因在于aData(1,1)的字符長度為256，Transpose所能夠處理的數(shù)組元素字符長度最大為255。有時就是需要處理這樣的數(shù)組元素，那么我們可以使用自定義函數(shù)進(jìn)行數(shù)組的行列轉(zhuǎn)置。TrasnposeArray可以實現(xiàn)二維數(shù)組的行列轉(zhuǎn)置。其效果與Transpose函數(shù)相同。

Sub Demo3()
  Dim aData(1 To 3, 1 To 2)
  For i = 1 To 3
    For j = 1 To 2
      aData(i, j) = i + j * 5
    Next j
  Next i
  aData(1, 1) = Application.Rept("$", 256)
  aTrans = TransposeArray(aData)
  Debug.Print UBound(aData, 1) & " x "; UBound(aData, 2)
  Debug.Print "=>>"
  Debug.Print UBound(aTrans, 1) & " x "; UBound(aTrans, 2)
End Sub
 
Function TransposeArray(arrA) As Variant
  Dim aRes()
  If VBA.IsArray(arrA) Then
    ReDim aRes(LBound(arrA, 2) To UBound(arrA, 2), LBound(arrA, 1) To UBound(arrA, 1))
    For i = LBound(arrA, 1) To UBound(arrA, 1)
      For j = LBound(arrA, 2) To UBound(arrA, 2)
        aRes(j, i) = arrA(i, j)
      Next
    Next
    TransposeArray = aRes
  End If
End Function

補(bǔ)充說明一點(diǎn)，由于Transpose本身是工作表函數(shù)，因此大家使用時，需要注意它的另一個限制，就是被轉(zhuǎn)置數(shù)組的最大行數(shù)是65,536。

以上這篇Transpose 數(shù)組行列轉(zhuǎn)置的限制方式就是小編分享給大家的全部內(nèi)容了，希望能給大家一個參考，也希望大家多多支持腳本之家。

您可能感興趣的文章: